Pequeño gran juego de Microbyte.
Una version minimalista de Worm of Bemer.
Juego original? chileno.
5 REM up 46 - W
6 REM down 62 - S
7 REM left 63 - A
8 REM right 58 - D
10 GRAPHICS 2:? #6:? #6;" OOOO@"
15 ? #6:? #6;"-------------- "
20 ? #6;" el gusano gloton"
25 ? #6;"--------------------"
30 ? #6:? #6;" ELIJA RAPIDEZ"
40 ? #6;" (1-9)"
50 INPUT Z:IF Z<1 OR Z>9 THEN RUN
60 DIM S(999):GRAPHICS 0:POKE 752,1
70 SETCOLOR 2,13,0:SETCOLOR 4,4,0
85 SCR=PEEK(88)+256*PEEK(89)
89 POSITION 1,12:? "OOOO@"
90 FOR K=1 TO 4:S(K)=1:NEXT K
100 A=4:B=1:X=12:Y=5:U=SCR+481:GOSUB 500
105 POKE 764,255
110 IF PEEK(764)=255 THEN 110
114 REM
115 REM ***** LOOP *****
120 F=X:C=Y
130 X=X+(PEEK(764)=62)-(PEEK(764)=46)
140 Y=Y+(PEEK(764)=58)-(PEEK(764)=63)
145 IF X=F AND Y=C THEN 120
150 IF X>=0 AND X<24 AND Y>=0 AND Y<40 THEN 165
160 POSITION 15,11:? "GAME OVER"
162 POSITION 2,21
163 IF PEEK(764)<>33 THEN 163
164 RUN
165 P=PEEK(SCR+40*X+Y)
170 IF P=47 OR P=32 THEN 160
180 IF P=0 THEN 200
190 L=L+P-16:GOSUB 500
200 POKE SCR+40*X+Y,32:A=A+1:IF A=1000 THEN A=1
205 S(A)=(X-F)*40+Y-C:POKE SCR+40*F+C,47
210 IF L THEN L=L-1:GOTO 440
220 POKE U,0:U=U+S(B):B=B+1:IF B=1000 THEN B=1
440 SOUND 0,6,13,13
441 SOUND 1,0,0,0
442 FOR K=1 TO 100-Z*10:NEXT K
443 SOUND 0,0,0,0
444 SOUND 1,11,13,13
445 GOTO 120
497 REM
498 REM ***** SUBRUTINA *****
499 REM
500 M=SCR+INT(RND(0)*24)*40+INT(RND(0)*40)
510 IF PEEK(M) THEN 500
520 POKE M,INT(RND(0)*9)+17:RETURN
